Sorting Glossary Lists in a DITA Bookmap

Suppose you have a DITA Bookmap that at some point references all of its glossary entries:

            <glossarylist>
                <topicref href="glossary/glossItem1.dita"/>
                <topicref href="glossary/glossItem2.dita"/>
                <topicref href="glossary/glossItem3.dita"/>
                <topicref href="glossary/glossItem4.dita"/>
            </glossarylist>

and you want to have all of these glossary topics sorted alphabetically by title as they appear in the PDF output.

The following steps will help you achieve this:

1. Somewhere on disk, create a folder (for example, customRefactor) and add a reference to it in the Oxygen Preferences->"XML / XML Refactoring" page.

2. In that custom folder, create an XML file (for example, sortGlossentries.xml) that has the following content:

   <refactoringOperationDescriptor 
       xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
       xmlns="http://www.oxygenxml.com/ns/xmlRefactoring" id="op_tck_rp1_hcb" name="Sort glossentries">
       <description>Sort glossentries.</description>    
       <script type="XSLT" href="sortGlossentries.xsl"/>
   </refactoringOperationDescriptor>

   This particular descriptor file contains the name of the operation, its description, and points to an XSLT stylesheet that will be applied to sort the entries in the DITA Bookmap.

3. In the same folder, create a file called sortGlossentries.xsl with the following content:

   <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
       xmlns:xs="http://www.w3.org/2001/XMLSchema"
       exclude-result-prefixes="xs"
       version="2.0">
       <xsl:template match="node() | @*">
           <xsl:copy>
               <xsl:apply-templates select="node() | @*"/>
           </xsl:copy>
       </xsl:template>
       <xsl:template match="glossarylist | topicgroup[@outputclass='glossarylist']">
           <xsl:copy>
               <xsl:apply-templates select="@*"/>
               <xsl:variable name="closestXMLLang" select="ancestor-or-self::*[attribute::xml:lang][1]/@xml:lang"/>
               <xsl:choose>
                   <xsl:when test="exists($closestXMLLang)">
                       <xsl:for-each select="*" >
                           <xsl:sort select="document(@href, .)/*/glossterm/text()" lang="{$closestXMLLang}" case-order="lower-first"/>
                           <xsl:apply-templates select="."/>
                       </xsl:for-each>
                   </xsl:when>
                   <xsl:otherwise>
                       <xsl:for-each select="*" >
                           <xsl:sort select="document(@href, .)/*/glossterm/text()" case-order="lower-first"/>
                           <xsl:apply-templates select="."/>
                       </xsl:for-each>
                   </xsl:otherwise>
               </xsl:choose>
           </xsl:copy>
       </xsl:template>
   </xsl:stylesheet>

   This particular XSLT processing copies almost all the Bookmap content unchanged. However, the topicrefs in the glossarylist are sorted according to the glossterm titles specified inside each of them.

4. Restart Oxygen.

5. Open the bookmap that contains the glossarylist in the Oxygen main editing area, right-click, choose Refactoring and in the Other operations submenu you will find the new Sort glossentries refactoring action. Invoke the action and use the Preview button to check if the sorting is properly done.